Network PC/Network PC.iso/amiga utilities/misc/commodities/screentab/installation-script

Text File | 1997-11-20 | 29.6 KB | 1,141 lines

; Installation-Script for ScreenTab V3.1c
; Author: Michael Link
; First creation : 28.10.94
; Last change    : 03.04.97

; @s English string section

(set #bad-version
    (cat "\n\nSorry, but ScreenTab requires\n"
         "at least Kickstart 2.04"
    )
)

(set #help-dir
    (cat "You must enter the name of the directory, in which\n"
         "ScreenTab shall be installed.\n\n"
         "If you want ScreenTab to be active everytime you\n"
         "start the computer, enter the directory\n"
         "\"SYS:WBStartup\", which is the default directory."
    )
)

(set #dir-request
    (cat "Please enter the destination directory\n"
         "for ScreenTab"
    )
)

(set #prefs-dir-request
    (cat "Please enter the destination directory\n"
         "for the ScreenTab-Preferences"
    )
)

(set #which-scrkey
    (cat "\n\nWith which key combination shall the\n"
         "screens be switched ?\n\n"
         "(Don't use any of the SHIFT-Keys, because\n"
         "ScreenTab needs them for back-switching !)"
    )
)

(set #which-winkey
    (cat "\n\nWith which key combination shall the\n"
         "windows be switched ?\n\n"
         "(Don't use any of the SHIFT-Keys, because\n"
         "ScreenTab needs them for back-switching !)"
    )
)

(set #msg-imagedir
    (cat "\n\nThe destination directory already contains\n"
         "a ScreenTab executable which will be updated.\n"
         "All icon settings will be preserved, but you\n"
         "should create a new tool-type IMAGEDIR after\n"
         "the installation which points to the directory\n"
         "containing your images."
    )
)

(set #write-tooltypes
    "\nWriting Tool-Types ..."
)

(set #old-prefs-file
    (cat "\n\nThere's an older preferences file installed\n"
         "on your system. If you want to use these\n"
         "preferences, they must be converted.\n\n"
         "Do you want to do this ?"
    )
)

(set #ask-plugins "\nWhich PlugIn-Modules do you want to install ?\n")

(set #ask-plugins-help
    (cat "PlugIn-Modules add new functionality to the Start-Button."
         "They can i. e. control commodities, eject changeable media "
         "or close windows.\n\n"
         "Please read the documentation for details."
    )
)

(set #ask-plugin-dir "\nChoose a directory for the modules ...\n")

(set #ask-brushes
    (cat "\n\nDo you want to install the\n"
         "included image-files (MWB-Style) ?"
    )
)

(set #ask-brushes-dir
    (cat "In which directory shall I create\n"
         "the ScreenTab-Images-Directory ?"
    )
)

(set #extracting-brushes "Extracting image files ...")

(set #ask-brushes-message
    (cat "\n\n\nH I N T"
         "\n\nThe easiest way to chose an image for an\n"
         "application or a startup node is to drag the icon\n"
         "of the image onto the image path gadget !"
    )
)

(set #ask-catalogs
    "\nWhich language catalogs shall be installed ?\n"
)

(set #ask-scrnotify
    (cat "\n\nIf available, ScreenTab uses\n"
         "the ScreenNotify-Library to react on changes\n"
         "of the Workbench resolution.\n\n"
         "Do you want to install this library ?"
    )
)

(set #ask-scrnotify-help
    (cat "The usage of this library is optional. "
         "But if the Workbench resolution is changed "
         "without this library installed, it can "
         "cause system instability or crashes.\n\n"
         "If you don't want to use an installed "
         "ScreenNotify-Library, set the tool-type "
         "USESCREENNOTIFY to NO."
    )
)

(set #ask-wbstarth
    (cat "\n\nScreenTab uses the WBStart-Handler by\n"
         "Stefan Becker to emulate a program start\n"
         "via Workbench.\n\n"
         "Do you want to install the handler now ?"
    )
)

(set #ask-wbstartl
    (cat "\n\nScreenTab uses the WBStart-Library by\n"
         "Stefan Becker to emulate a program start\n"
         "via Workbench.\n\n"
         "Do you want to install the library now ?"
    )
)

(set #copy-screentab
    "\n\nCopying ScreenTab ..."
)

(set #copy-screentabprefs
    "\n\nCopying ScreenTabPrefs ..."
)

(set #copy-plugin
    "\n\nCopying PlugIn-Module ..."
)

(set #copy-brushes
    "\n\nCopying Image-Files ..."
)

(set #copy-scrnotify
    "\n\nCopying ScreenNotify-Library ..."
)

(set #copy-wbstarth
    "\n\nCopying WBStart-Handler ..."
)

(set #copy-wbstartl
    "\n\nCopying WBStart-Libraries ..."
)

(set #copy-catalogs
    "\n\nCopying language catalogs ..."
)

(set #catalog-choice-default 0)

(set #lang-german   "Deutsch" )
(set #lang-french   "Français" )
(set #lang-italian  "Italiano" )

(set #error-conversion
    "\n\nError during conversion !!!"
)

(set #error-prefs
    (cat "\n\nAn error occured during checking of the version\n"
         "of the preferences file. Probably this happened\n"
         "because you are using a file of the first ScreenTab\n"
         "version (1.13).\n\n"
         "This version isn't supported anymore !"
    )
)
; @e

; @s German string section

(if (= @language "deutsch")
(

(set #bad-version
    (cat "\n\nSorry, aber ScreenTab läuft erst ab\n"
         "Kickstart 2.04."
    )
)

(set #help-dir
    (cat "An dieser Stelle müssen Sie angeben, in welchem\n"
      "Verzeichnis ScreenTab installiert werden soll.\n\n"
      "Wenn ScreenTab gleich nach dem Start des Computers\n"
      "aktiv sein soll, sollten Sie als Zielverzeichnis\n"
      "\"SYS:WBStartup\" angeben."
    )
)

(set #dir-request
    (cat "Geben Sie jetzt das Verzeichnis an,\n"
         "in dem ScreenTab installiert werden soll."
    )
)

(set #prefs-dir-request
    (cat "Geben Sie jetzt das Verzeichnis an, in das das\n"
         "Voreinstellungsprogramm kopiert werden soll."
    )
)

(set #which-scrkey
    (cat "\n\nMit welcher Tastenkombination sollen die\n"
         "Screens umgeschaltet werden ?\n\n"
         "(Bitte geben Sie hier keine SHIFT-Taste an, da\n"
         "diese für das Zurückblättern gebraucht werden !)"
    )
)

(set #which-winkey
    (cat "\n\nMit welcher Tastenkombination sollen die\n"
         "Fenster umgeschaltet werden ?\n\n"
         "(Bitte geben Sie hier keine SHIFT-Taste an, da\n"
         "diese für das Zurückblättern gebraucht werden !)"
    )
)

(set #msg-imagedir
    (cat "\n\nDas Zielverzeichnis enthält bereits eine\n"
         "ScreenTab-Version, die hiermit ersetzt wird.\n"
         "Alle Einstellungen werden erhalten, allerdings\n"
         "sollten Sie einen neuen Tool-Type IMAGEDIR anlegen,\n"
         "der auf das Verzeichnis zeigt, das die Images enthält."
    )
)

(set #write-tooltypes
    "\nSchreibe Tool-Types ..."
)

(set #old-prefs-file
    (cat "\n\nEine ältere Voreinstellungsdatei ist auf\n"
         "ihrem System installiert. Um diese Einstellungen\n"
         "mit der neuen Version nutzen zu können, muß\n"
         "eine Konvertierung vorgenommen werden.\n\n"
         "Wollen Sie das ?"
    )
)

(set #ask-plugins "\nWelche PlugIn-Module wollen Sie installieren ?\n")

(set #ask-plugins-help
    (cat "PlugIn-Module erweitern die Funktionalität des "
         "Start-Buttons. Mit ihnen können beispielsweise "
         "die Commodities kontrolliert, Wechselmedien "
         "ausgeworfen oder Fenster geschlossen werden.\n\n"
         "Bitte lesen Sie dazu die Dokumentation."
    )
)

(set #ask-plugin-dir
    "\nBitte wählen Sie ein Verzeichnis für die PlugIn-Module ...\n"
)

(set #ask-brushes
    (cat "\n\nWollen Sie die mitgelieferten Image-Dateien\n"
         "installieren (MWB-Stil) ?"
    )
)

(set #ask-brushes-dir
    (cat "In welches Verzeichnis sollen die Image-Dateien\n"
         "kopiert werden ? Ein Verzeichnis mit dem Namen\n"
         "'ScreenTab-Images' wird dort angelegt"
    )
)

(set #extracting-brushes "Entpacke Image-Dateien ...")

(set #ask-brushes-message
    (cat "\n\n\nH I N W E I S"
         "\n\nAm einfachsten ordnen Sie einer Anwendung\n"
         "oder einem Startup-Eintrag ein Image zu, indem\n"
         "Sie das Icon des Image auf das Eingabefeld für\n"
         "den Image-Pfad ziehen."
    )
)

(set #ask-catalogs
    "\nWelche Sprach-Kataloge sollen installiert werden ?\n"
)

(set #ask-scrnotify
    (cat "\n\nScreenTab benutzt, falls vorhanden,\n"
         "die ScreenNotify-Library, um auf Wechsel der\n"
         "Workbench-Auflösung reagieren zu können.\n\n"
         "Wollen Sie diese Library installieren ?"
    )
)

(set #ask-scrnotify-help
    (cat "Die Benutzung dieser Library ist optional. "
         "Allerdings kann es zu Fehlern oder Abstürzen "
         "kommen, wenn die Workbench-Auflösung ohne "
         "installierte Library gewechselt wird.\n\n"
         "Wenn Sie auf die ScreenNotify-Library "
         "verzichten wollen, können Sie dies gezielt "
         "mit dem Tool-Type USESCREENNOTIFY unterbinden, "
         "indem Sie ihn auf NO setzen."
    )
)

(set #ask-wbstarth
    (cat "\n\nScreenTab braucht den WBStart-Handler von\n"
         "Stefan Becker, um einen Programmstart über die\n "
         "Workbench zu emulieren.\n\n"
         "Wollen Sie den Handler jetzt installieren ?"
    )
)

(set #ask-wbstartl
    (cat "\n\nScreenTab braucht die WBStart-Library von\n"
         "Stefan Becker, um einen Programmstart über die\n"
         "Workbench zu emulieren.\n\n"
         "Wollen Sie die Library jetzt installieren ?\n"
    )
)

(set #copy-screentab
    "\n\nKopiere ScreenTab ..."
)

(set #copy-screentabprefs
    "\n\nKopiere ScreenTabPrefs ..."
)

(set #copy-plugin
    "\n\nKopiere PlugIn-Module ..."
)

(set #copy-brushes
    "\n\nKopiere Image-Dateien ..."
)

(set #copy-scrnotify
    "\n\nKopiere ScreenNotify-Library ..."
)

(set #copy-wbstarth
    "\n\nKopiere WBStart-Handler ..."
)

(set #copy-wbstartl
    "\n\nKopiere WBStart-Libraries ..."
)

(set #copy-catalogs
    "\n\nKopiere Sprachkataloge ..."
)

(set #catalog-choice-default 1)

(set #error-conversion
    "\n\nFehler beim Konvertieren !!!"
)

(set #error-prefs
    (cat "\n\nBeim der Versions-Überprüfung der Voreinstellungs-\n"
         "datei trat ein Fehler auf. Wahrscheinlich benutzen\n"
         "Sie noch eine Datei der ersten ScreenTab-Version (1.13).\n\n"
         "Diese wird jedoch nicht mehr unterstützt !"
    )
)

)
) ; endif

; @e

; @s Français string section

(if (= @language "français")
(

(set #bad-version
    (cat "\n\nDésolé, mais ScreenTab requiert\n"
         "au moins le Kickstart 2.04"
    )
)

(set #help-dir
    (cat "Vous devez entrer le nom du répertoire, dans lequel\n"
         "ScreenTab doit être installé.\n\n"
         "Si vous voulez activer ScreenTab à chaque démarrage de\n"
         "l'ordinateur, entrez le répertoire\n"
         "\"SYS:WBStartup\", lequel est un répertoire par défaut."
    )
)

(set #dir-request
    (cat "Entrez le répertoire destination\n"
         "pour ScreenTab"
    )
)

(set #prefs-dir-request
    (cat "Entrez le répertoire destination\n"
         "pour les Préférences-ScreenTab"
    )
)

(set #which-scrkey
    (cat "\n\nAvec quelle combinaison de touche les\n"
         "écrans doivent être switchés ?\n\n"
         "(N'utilisez pas les touches-SHIFT, car\n"
         "ScreenTab en a besoin pour switcher en arrière !)"
    )
)

(set #which-winkey
    (cat "\n\nAvec quelle combinaison de touche les\n"
         "fenêtres doivent être switchés ?\n\n"
         "(N'utilisez pas les touches-SHIFT, car\n"
         "ScreenTab en a besoin pour switcher en arrière !)"
    )
)

(set #msg-imagedir
    (cat "\n\nLe répertoire destination contient déjà\n"
         "l'éxecutable ScreenTab lequel sera mis à jour.\n"
         "Les réglages des icônes seront préservées, mais vous\n"
         "devrez créer un nouveau tool-type IMAGEDIR après\n"
         "l'installation contenant le chemin du répertoire\n"
         "vers vos images."
    )
)

(set #write-tooltypes
    "\nEcriture des Tool-Types ..."
)

(set #old-prefs-file
    (cat "\n\nIl ya à un déjà un ancien fichier préférences installé\n"
         "sur votre système. Si vous voulez les utiliser, ces\n"
         "préférences doivent être converties.\n\n"
         "Voulez-vous faire ça ?"
    )
)

(set #ask-plugins "\nQuels Modules-PlugIn voulez-vous installer ?\n")

(set #ask-plugins-help
    (cat "Les Modules-PlugIn ajoutent de nouvelles fonctions au Bouton-Démarrage."
         "Ils peuvent controller les commoditées, éjecter un média, fermer"
         "des fenêtres...\n\n"
         "Lisez la documentation pour plus de détails."
    )
)

(set #ask-plugin-dir "\nChoisissez un répertoire pour les modules ...\n")

(set #ask-brushes
    (cat "\n\nVoulez-vous installer les\n"
         "fichiers-images inclus (Style-MWB) ?"
    )
)

(set #ask-brushes-dir
    (cat "Dans quel répertoire dois-je créer\n"
         "le répertoire Images-ScreenTab ?"
    )
)

(set #extracting-brushes "Extraction fichiers images...")

(set #ask-brushes-message
    (cat "\n\n\nH I N T"
         "\n\nLa manière la plus facile de choisir une image pour une\n"
         "application ou un noeud de démarrage est d'amener l'icône\n"
         "de l'image sur le gadget du chemin image !"
    )
)

(set #ask-catalogs
    "\nQuel language dois être installé ?\n"
)

(set #ask-scrnotify
    (cat "\n\nSi disponible, ScreenTab utilise\n"
         "la ScreenNotify-Library pour réagir sur les changements\n"
         "de résolution du Workbench.\n\n"
         "Voulez-vous installer cette library ?"
    )
)

(set #ask-scrnotify-help
    (cat "L'usage de cette library est optionnelle. "
         "Mais si la résolution du Workbench est changée "
         "sans que cette library soit installée, cela peut"
         "causer une instabilité du système ou un crash.\n\n"
         "Si vous ne voulez pas utiliser la "
         "ScreenNotify-Library, réglez le tool-type "
         "USESCREENNOTIFY à NO."
    )
)

(set #ask-wbstarth
    (cat "\n\nScreenTab utilise le WBStart-Handler de\n"
         "Stefan Becker pour émuler le démarrage d'un programme\n"
         "via Workbench.\n\n"
         "Voulez-vous installer ce handler maintenant ?"
    )
)

(set #ask-wbstartl
    (cat "\n\nScreenTab utilise la WBStart-Library de\n"
         "Stefan Becker pour émuler le démarrage d'un programme\n"
         "via Workbench.\n\n"
         "Voulez-vous installer cette library maintenant ?"
    )
)

(set #copy-screentab
    "\n\nCopie ScreenTab..."
)

(set #copy-screentabprefs
    "\n\nCopie ScreenTabPrefs..."
)

(set #copy-plugin
    "\n\nCopie Module-PlugIn..."
)

(set #copy-brushes
    "\n\nCopie Fichiers-Images..."
)

(set #copy-scrnotify
    "\n\nCopie ScreenNotify-Library..."
)

(set #copy-wbstarth
    "\n\nCopie WBStart-Handler..."
)

(set #copy-wbstartl
    "\n\nCopie WBStart-Libraries..."
)

(set #copy-catalogs
    "\n\nCopie catalogues des langues..."
)

(set #catalog-choice-default 2)

(set #lang-german   "Deutsch" )
(set #lang-italian  "Italiano" )
(set #lang-french   "Français" )

(set #error-conversion
    "\n\nErreur durant la conversion !!!"
)

(set #error-prefs
    (cat "\n\nUne erreur est survenue durant la vérification de la version\n"
         "du fichier préférences. Ceci est probablement dû\n"
         "à votre utilisation d'un fichier de la première version de\n"
         "ScreenTab version (1.13).\n\n"
         "Cette version n'est plus supportée du tout !"
    )
)

)
) ; endif
; @e

; @s Italian string section

(if (= @language "italiano")
(

(set #bad-version
    (cat "\n\nMi spiace, ma ScreenTab ha bisogno almeno\n"
         "della Kickstart 2.04."
    )
)

(set #help-dir
    (cat "Dovete scrivere il nome della directory, dove\n"
      "ScreenTab deve essere installato.\n\n"
      "Se volete che ScreenTab sia attivo ogni qualvolta avviate\n"
      "il Computer, ponete la directory \"SYS:WBStartup\"\n"
      "che è la directory standard."
    )
)

(set #dir-request
    (cat "Per favore ponete la directory di destinazione,\n"
         "dove volete installare ScreenTab."
    )
)

(set #prefs-dir-request
    (cat "Per favore ponete la directory di destinazione,\n"
         "dove volete installare ScreenTab-Prefs."
    )
)

(set #which-scrkey
    (cat "\n\nCon quale combinazione tasti dovranno essere\n"
         "commutati gli schermi ?\n\n"
         "(Non usate uno dei tasti SHIFT, perchè ScreenTab\n"
         "necessita di essi per commutare all'indietro !)"
    )
)

(set #which-winkey
    (cat "\n\nCon quale combinazione tasti dovranno essere\n"
         "commutate le finestre ?\n\n"
         "(Non usate uno dei tasti SHIFT, perchè ScreenTab\n"
         "necessita di essi per commutare all'indietro !)"
    )
)

(set #msg-imagedir
    (cat "\n\nLa directory di destinazione già contiene\n"
         "ScreenTab che sarà aggiornato.\n"
         "Tutte le configurazioni nell'icona saranno preservate,\n"
         "dovrai creare un nuovo tool-type IMAGEDIR dopo\n"
         "l'installazione che descriva il percorso della directory\n"
         "contenente le vostre immagini."
    )
)

(set #write-tooltypes
    "\nSto scrivendo i Tool-Type ..."
)

(set #old-prefs-file
    (cat "\n\nE' presente un file preferenze precedente\n"
         "nel vostro sistema. Se volete usare queste\n"
         "preferenze, deve essere convertito.\n\n"
         "Lo volete ?"
    )
)

(set #ask-plugins "\nQuali Moduli volete installare ?\n")

(set #ask-plugins-help
    (cat "I Moduli PlugIn aggiungono nuove funzionalità al pulsante Start."
         "Possono ad esempio controllare commodities, espellere media "
         "modificabili o chiudere finestre.\n\n"
         "Per favore leggete la documentazione per i dettagli."
    )
)

(set #ask-plugin-dir
    "\nScegliete una directory per i moduli ...\n"
)

(set #ask-brushes
    (cat "\n\nVolete installare le immagini\n"
         "fornite (Stile-MWB) ?"
    )
)

(set #ask-brushes-dir
    (cat "In quale directory dovrò creare\n"
         "il cassetto ScreenTab-Images ?"
    )
)

(set #extracting-brushes "Sto estraendo i file immagine ...")

(set #ask-brushes-message
    (cat "\n\n\nC O N S I G L I O"
         "\n\nIl modo più semplice per scegliere una immagine per una\n"
         "applicazione o un nodo di startup è di trascinare l'icona\n"
         "dell'immagine dentro il percorso del gadget immagine !"
    )
)

(set #ask-catalogs
    "\nQuale lingua devo installare ?\n"
)

(set #ask-scrnotify
    (cat "\n\nSe disponibile, ScreenTab usa\n"
         "la ScreenNotify-Library che interviene sui cambiamenti\n"
         "di risoluzione del Workbench.\n\n"
         "Volete installare questa libreria ?"
    )
)

(set #ask-scrnotify-help
    (cat "L'utilizzo di questa libreria è facoltativo. "
         "Ma se la risoluzione del Workbench è modificata "
         "senza che questa libreria sia installata, può "
         "causare instabilità al sistema o crash.\n\n"
         "Se non volete usare la ScreenNotify-Library, "
         " ponete il tool-type "
         "USESCREENNOTIFY a NO."
    )
)

(set #ask-wbstarth
    (cat "\n\nScreenTab usa WBStart-Handler di\n"
         "Stefan Becker per emulare un avvio di programma\n"
         "via Workbench.\n\n"
         "Volete installare l'handler adesso ?"
    )
)

(set #ask-wbstartl
    (cat "\n\nScreenTab usa WBStart-Library di\n"
         "Stefan Becker per emulare un avvio di programma\n"
         "via Workbench.\n\n"
         "Volete installare la libreria adesso ?"
    )
)

(set #copy-screentab
    "\n\nSto copiando ScreenTab ..."
)

(set #copy-screentabprefs
    "\n\nSto copiando ScreenTabPrefs ..."
)

(set #copy-plugin
    "\n\nSto copiando i Moduli PlugIn ..."
)

(set #copy-brushes
    "\n\nSto copiando i file Immagine ..."
)

(set #copy-scrnotify
    "\n\nSto copiando la ScreenNotify-Library ..."
)

(set #copy-wbstarth
    "\n\nSto copiando la WBStart-Handler ..."
)

(set #copy-wbstartl
    "\n\nSto copiando la WBStart-Library ..."
)

(set #copy-catalogs
    "\n\nSto copiando i cataloghi ..."
)

(set #catalog-choice-default 4)

(set #error-conversion
    "\n\nErrore durante la conversione !!!"
)

(set #error-prefs
    (cat "\n\nUn errore è occorso durante il controllo della versione\n"
         "del file preferenze. Probabilmente questo è avvenuto perchè\n"
         "state usando un file di una versione antecedente ScreenTab\n"
         "versione (1.13).\n\n"
         "Questa versione non è più supportata !"
    )
)

)
) ; endif

; @e

; @s Different version numbers

(set intuition_vernum (getversion "intuition.library" (resident)))
(set intuition_ver    (shiftright intuition_vernum 16))
(set locale_vernum    (getversion "locale.library" (resident)))
(set locale_ver       (shiftright locale_vernum 16))
(set scrntfy_vernum   (getversion "LIBS:screennotify.library"))
(set scrntfy_ver      (shiftright scrntfy_vernum 16))
(set wbstarth_vernum  (getversion "L:WBStart-Handler"))
(set wbstarth_ver     (shiftright wbstarth_vernum 16))
(set wbstartl_vernum  (getversion "LIBS:wbstart.library"))
(set wbstartl_ver     (shiftright wbstartl_vernum 16))

; @e

; @s check OS version and CPU
(if (< intuition_ver 37)
    (abort #bad-version)
)

(set #cpu020 (not (patmatch "68000|68010" (database "cpu"))))
; @e

; @s Ask for destination directory

(set DIR (askdir (prompt #dir-request)
                 (help #help-dir)
                 (default "SYS:WBStartup")
         )
)

(set PREFSDIR (askdir (prompt #prefs-dir-request)
                      (help @askdir-help)
                      (default "SYS:Prefs")
              )
)

(if (askbool (prompt #ask-brushes)
             (help)
             (default 1)
    )
    (
        (set #extract-images 1)

        (set #brush-dir (askdir (prompt #ask-brushes-dir)
                                (help @askdir-help)
                                (default "SYS:Prefs")
                        )
        )

        (set #brush-dir (tackon #brush-dir "ScreenTab-Images"))
    )
)

; @e

; @s Tool-Types and copy main program

(set @default-dest DIR)

(set #oldversion-exists (exists (tackon DIR "ScreenTab") (noreq) ) )

; we must check if an old version is still in this directory
(if (= #oldversion-exists 0)
    (
        (set SWITCHKEY (askstring (prompt #which-scrkey)
                                  (help @askstring-help)
                                  (default "LCommand Tab")
                       )
        )

        (set WINSWITCHKEY (askstring (prompt #which-winkey)
                                  (help @askstring-help)
                                  (default "LCommand `")
                          )
        )

        (tooltype (prompt #write-tooltypes)
                  (help)
                  (if (= #cpu020 0) (dest "ScreenTab") (dest "ScreenTab.020"))
                  (settooltype "SWITCHKEY" SWITCHKEY)
                  (settooltype "WINSWITCHKEY" WINSWITCHKEY)
                  (if (= #extract-images 1) (settooltype "IMAGEDIR" #brush-dir) )
        )
    )
    (
        (message #msg-imagedir)
    )
)

(copyfiles (prompt #copy-screentab)
           (help @copyfiles-help)
           (if (= #cpu020 0) (source "ScreenTab") (source "ScreenTab.020"))
           (newname "ScreenTab")
           (dest DIR)
           (if (= #oldversion-exists 0) (infos) )
)

(set @default-dest PREFSDIR)

(copyfiles (prompt #copy-screentabprefs)
           (help @copyfiles-help)
           (source "Prefs/ScreenTabPrefs")
           (dest PREFSDIR)
           (infos)
)

; @e

; @s Checking for preferences file and need for conversion

(if (exists "ENVARC:ScreenTab.prefs")
    (
        (set #check-prefsversion (run "HandleScrTab PREFSVERSION" (safe) ) )

        (if (> #check-prefsversion 1)
            (message #error-prefs)
        )

        (if (= #check-prefsversion 1)
            (if (askbool (prompt #old-prefs-file)
                         (help)
                         (default 1)
                )
                (if (> (run "HandleScrTab CONVERTPREFS" (safe) ) 0)
                    (copyfiles (prompt)
                               (help)
                               (source "T:SCRT.TMP")
                               (dest "ENVARC:")
                               (newname "ScreenTab.prefs")
                    )
                    (message #error-conversion)
                )
            )
        )
    )
    (copyfiles (prompt #copy-preferences)
               (help)
               (source "ScreenTab.prefs")
               (dest "ENVARC:")
    )
)

; @e

; @s Installation of the PlugIn-Modules

(set #plugin-choice (askoptions (prompt #ask-plugins)
                                (help #ask-plugins-help)
                                (choices "Commodities"
                                         "Windows"
                                         "SysTools"
                                         "PasteClip")
                    )
)

(if #plugin-choice
    (
        (set #plugin-dir (askdir (prompt #ask-plugin-dir)
                                 (help @askfile-help)
                                 (default "LIBS:plugins")
                         )
        )

        (set n 0)

        (while (set #plugin (select n "commodities.plugin"
                                      "windows.plugin"
                                      "systools.plugin"
                                      "pasteclip.plugin"
                                      ""
                            )
               )
               (if (IN #plugin-choice n)
                   (
                       (set #plugin-source (tackon "PlugIns" #plugin))

                       (copylib (prompt #copy-plugin)
                                (help)
                                (source #plugin-source)
                                (dest #plugin-dir)
                       )
                   )
               )

               (set n (+ n 1))
        )
    )
)

; @e

; @s Extracting of the images
(if (= #extract-images 1)
    (
        (makedir #brush-dir
                 (prompt)
                 (help @makedir-help)
                 (infos)
        )

        (set #exelha (cat "lha e Images.lha \""
                          #brush-dir "/\""
                     )
        )

        (working #extracting-brushes)

        (run #exelha)

        (message #ask-brushes-message)
    )
)

; @e

; @s Installation of the ScreenNotify-Library

(if (= scrntfy_ver 0)
    (if (askbool (prompt #ask-scrnotify)
                 (help   #ask-scrnotify-help)
                 (default 1)
        )
        (copylib (prompt #copy-scrnotify)
                 (help)
                 (source "Libs/screennotify.library")
                 (dest   "LIBS:")
                 (confirm)
        )
    )
)

; @e

; @s Installation of the WBStart-Library or -Handler

; we can only use WBStart-Library with OS 3.x
(if (>= intuition_ver 39)
    (if (= wbstartl_ver 0)
        (if (askbool (prompt #ask-wbstartl)
                     (help)
                     (default 1)
            )
            (
                (copylib (prompt #copy-wbstartl)
                         (help)
                         (source "Libs/wbstart.library")
                         (dest   "LIBS:")
                         (confirm)
                )
                (copylib (prompt #copy-wbstartl)
                         (help)
                         (source "Libs/dospath.library")
                         (dest   "LIBS:")
                         (confirm)
                )
            )
        )
    )
    (if (= wbstarth_ver 0)
        (if (askbool (prompt #ask-wbstarth)
                     (help)
                     (default 1)
            )
            (copylib (prompt #copy-wbstarth)
                     (help)
                     (source "L/WBStart-Handler")
                     (dest   "L:")
                     (confirm)
            )
        )
    )
)

; @e

; @s Installation of the catalogs

(if (>= locale_ver 38)
    (
        (set #catalogs (askoptions (prompt #ask-catalogs)
                                   (help)
                                   (choices #lang-german #lang-french #lang-italian)
                                   (default #catalog-choice-default)
                       )
        )

        (if (> #catalogs 0)
            (
                (set n 0)

                (while (set #language (select n "deutsch" "français" "italiano" ""))

                    (if (IN #catalogs n)
                        (
                            (set #dstpath (tackon (tackon "LOCALE:Catalogs" #language) "ScreenTab"))

                            (if (NOT (exists #dstpath))
                                (makedir #dstpath
                                         (prompt)
                                         (help @makedir-help)
                                )
                            )

                            (set #srcpath (cat "catalogs/"
                                               #language
                                          )
                            )

                            (copyfiles (prompt #copy-catalogs)
                                       (help)
                                       (source #srcpath)
                                       (dest   #dstpath)
                                       (pattern "#?.catalog")
                            )

                            (if #plugin-choice
                                (
                                    (set #dstpath-plugins (tackon #dstpath "PlugIns"))

                                    (if (NOT (exists #dstpath-plugins))
                                        (makedir #dstpath-plugins
                                                 (prompt)
                                                 (help @makedir-help)
                                        )
                                    )

                                    (set #srcpath-plugins (tackon #srcpath "PlugIns"))

                                    (copyfiles (prompt #copy-catalogs)
                                               (help)
                                               (source #srcpath-plugins)
                                               (dest   #dstpath-plugins)
                                               (pattern "#?.catalog")
                                    )
                                )
                            )
                        )
                    )

                    (set n (+ n 1))
                )
            )
        )
    )
)

; @e